Funcions de matriu

Contingut

# Array Functions

Esta categoria conté les funcions de matriu.

## Què és una matriu?

Una matriu és un interval de cel·les enllaçades que contenen valors en un full de càlcul. Un interval quadrat de 3 files i 3 columnes és una matriu de 3 x 3:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

La matriu més petita possible és una matriu de 1 x 2 o 2 x 1 amb dues cel·les adjacents.

## Què és una fórmula matricial?

Una fórmula matricial és una fórmula en què s'avaluen els valors individuals d'un interval de cel·les. La diferència entre una fórmula matricial i altres tipus de fórmules és que la fórmula matricial tracta diversos valors simultàniament, en comptes de tractar-ne només un.

Una fórmula matricial no només pot processar diferents valors, sinó que també pot retornar-ne de diferents. Els resultats d'una fórmula matricial és també una matriu.

To multiply the values in the individual cells by 10 in the above array, you do not need to apply a formula to each individual cell or value. Instead you just need to use a single array formula. Select a range of 3 x 3 cells on another part of the spreadsheet, enter the formula =10*A1:C3 and confirm this entry using the key combination CommandCtrl + Shift + Enter. The result is a 3 x 3 array in which the individual values in the cell range (A1:C3) are multiplied by a factor of 10.

A més de la multiplicació, també podeu utilitzar altres operadors en l'àrea de referència (una matriu). Amb el LibreOffice Calc, podeu sumar (+), restar (-), multiplicar (*), dividir (/), utilitzar exponents (^), concatenació (&) i comparacions (=, <>, <, >, <=, >=). Els operadors es poden utilitzar en cada valor individual de l'àrea de les cel·les i retornar el resultat com una matriu si s'ha introduït la fórmula matricial.

Els operadors de comparació d'una fórmula matricial tracten les cel·les buides de la mateixa manera que en una fórmula normal, és a dir, com un zero o com una cadena buida. Per exemple, si les cel·les A1 i A2 són buides, les fórmules matricials {=A1:A2=""} i {=A1:A2=0} retornaran una matriu d'una columna i dues línies que contindrà CERT.

### Quan podeu utilitzar fórmules matricials?

Utilitzeu fórmules matricials si heu de repetir càlculs amb valors diferents. Si decidiu canviar el mètode de càlcul més avant, només caldrà que actualitzeu la fórmula matricial. Per afegir una fórmula matricial, seleccioneu tot l'interval de matriu i, tot seguit, feu la modificació a la fórmula matricial.

Les fórmules matricials també són una opció que estalvia espai quan s'han de calcular diversos valors, ja que no consumeixen gaire memòria. A més a més, les matrius són eines essencials per fer càlculs complexos, ja que podeu incloure diversos intervals de cel·les en els càlculs. El LibreOffice disposa de diverses funcions matemàtiques per a les matrius, com ara la funció MULTM per multiplicar dues matrius o la funció SUMAPRODUCTE per calcular els productes escalars de dues matrius.

## Ús de fórmules matricials al LibreOffice Calc

### Implicit intersection of array formulas

You can also create a "normal" formula in which the reference range, such as parameters, indicate an array formula. This formula is also known as "implicit intersection" of array formula. The result is obtained from the intersection of the reference range and the rows or columns in which the formula is found. If there is no intersection or if the range at the intersection covers several rows or columns, a #VALUE! error message appears. The following example illustrates this concept:

In the table above, place the array formula in D1:

{=A1:A3 + 100}

Cells D1, D2, D3 have values 107, 195, 105 respectively.

Insert the formula below in E2, do not enter as array formula.

=A1:A3 + 100

Cells E1 and E3 are empty, Cell E2 has value 195. This is the implicit intersection of array formulas.

Insert formula below in E4, as in E2.

=A1:A3 + 100

Cell E4 display #VALUE!. Row 4 is out of the range A1:A3 of the formula.

### Creació de fórmules matricials

Si creeu una fórmula matricial mitjançant l'Auxiliar de funcions, heu d'activar la casella de selecció Matriu cada vegada perquè es retornen els resultats en una matriu. Si no ho feu, només es retorna el valor de la cel·la superior esquerra de la matriu que es calcula.

If you enter the array formula directly into the cell, you must use the key combination Shift + CommandCtrl + Enter instead of the Enter key. Only then does the formula become an array formula.

Les fórmules matricials apareixen entre claus al LibreOffice Calc. No podeu crear fórmules matricials introduint-hi les claus manualment.

The cells in a results array are automatically protected against changes. However, you can edit, delete or copy the array formula by selecting the entire array cell range.

### Ús de constants de matriu en línia en fórmules

El Calc admet constants de matriu en línia en les fórmules. Una matriu en línia es troba entre claudàtors '{' i '}'. Els elements poden ser nombres (inclosos els negatius), una constant lògica (CERT, FALS) o una cadena literal. No es permeten les expressions no constants. Es poden introduir les matrius en una fila o en més d'una, i en una columna o en més d'una. Totes les files han de constar del mateix nombre d'elements i totes les columnes han d'estar formades pel mateix nombre d'elements.

El separador de columnes (que separa els elements d'una fila) i el separador de files depenen de la llengua i de la configuració regional. Però al contingut d'esta ajuda, s'utilitzen el punt i coma ';' i el símbol de barra vertical '|' per indicar els separadors de columnes i de files, respectivament. Per exemple, en anglés s'utilitza la coma ',' com a separador de columnes i el punt i coma ';', com a separador de files.

És possible veure i modificar el separador de files i columnes a LibreOffice ▸ PreferènciesEines ▸ Opcions ▸ Calc ▸ Fórmula ▸ Separadors.

No es poden incrustar les matrius.

Exemples:

={1;2;3}

Una matriu amb una fila formada pels nombres 1, 2 i 3.

To enter this array constant, you select three cells in a row, then you type the formula ={1;2;3} using the curly braces and the semicolons, then press CommandCtrl + Shift + Enter.

={1;2;3|4;5;6}

Una matriu amb dues files i tres valors en cada fila.

={0;1;2|FALS;CERT;"dos"}

Una matriu de dades mixtes.

=SIN({1;2;3})

En introduir-lo com una fórmula matricial, retorna el resultat de tres càlculs de SIN amb els arguments 1, 2 i 3.

### Edició de fórmules matricials

1. Select the cell range or array containing the array formula. To select the whole array, position the cell cursor inside the array range, then press CommandCtrl + /, where / is the division key on the numeric keypad.

2. Premeu F2 o col·loqueu el cursor en la línia d'entrada. Totes dues accions vos permeten editar la fórmula.

3. After you have made changes, press CommandCtrl + Shift + Enter.

Podeu donar format a parts separades d'una matriu. Per exemple, en podeu canviar el color del tipus de lletra. Seleccioneu un interval de cel·les i llavors canvieu l'atribut que vulgueu.

### Supressió de fórmules matricials

1. Select the cell range or array containing the array formula. To select the whole array, position the cell cursor inside the array range, then press CommandCtrl + /, where / is the division key on the numeric keypad.

2. Premeu Supr per a suprimir el contingut de la matriu, inclosa la fórmula matricial, o bé, premeu Retrocés perquè aparega el diàleg Suprimeix el contingut. Seleccioneu Fórmula o Suprimeix-ho tot i feu clic a D'acord.

### Còpia de fórmules matricials

1. Seleccioneu l'àrea de les cel·les o la matriu que continga la fórmula matricial.

2. Premeu F2 o col·loqueu el cursor en la línia d'entrada.

3. Copy the formula into the input line by pressing CommandCtrl + C.

4. Select a range of cells where you want to insert the array formula and either press F2 or position the cursor in the input line.

5. Paste the formula by pressing CommandCtrl + V in the selected space and confirm it by pressing CommandCtrl + Shift + Enter. The selected range now contains the array formula.

### Ajust d'una àrea de matriu

Si voleu editar la matriu d'eixida, feu el següent:

1. Seleccioneu l'àrea de les cel·les o la matriu que continga la fórmula matricial.

2. A sota de la selecció, a la dreta, veureu una icona petita amb la qual podeu apropar-vos o allunyar-vos de l'àrea utilitzant el ratolí.

Quan ajusteu l'interval de matriu, la fórmula matricial no s'ajusta automàticament. Només canvieu l'interval on apareixerà el resultat.

By holding down the CommandCtrl key, you can create a copy of the array formula in the given range.

### Càlcul de matrius condicionals

Un càlcul de matriu condicional és una matriu o una fórmula matricial que inclou una funció SI() o TRIA(). L'argument de condició de la fórmula és una referència d'àrees o un resultat de matriu.

En l'exemple següent, s'aplica la verificació >0 de la fórmula {=SI(A1:A3>0;"sí";"no")} a cadascuna de les cel·les de l'interval A1:A3 i el resultat es copia a la cel·la corresponent.

| A | B (fórmula) | B (resultat)
1 | 1 | {=SI(A1:A3>0;"sí";"no")} | sí
2 | 0 | {=SI(A1:A3>0;"sí";"no")} | no
3 | 1 | {=SI(A1:A3>0;"sí";"no")} | sí

Les funcions següents permeten gestionar les matrius forçades: CORREL, COVAR, PRONOSTIC, PROVAF, INTERCEPCIO, DETERMM, MINVERSA, MULTM, MODA, PEARSON, PROB, RQUAD, PENDENT, ERRTIPYX, SUMAPRODUCTE, SUMAX2MENYSY2, SUMAX2MESY2, SUMAXMENYSY2 i PROVAT. Si utilitzeu referències d'àrea com a arguments quan apliqueu una d'estes funcions, les funcions es comporten com funcions de matriu. La taula següent mostra un exemple de gestió de matrius forçades:

| A | B (fórmula) | B (resultat) | C (fórmula matricial forçada) | C (resultat)
1 | 1 | =A1:A2+1 | 2 | =SUMAPRODUCTE(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMAPRODUCTE(A1:A2+1) | 5
3 |  | =A1:A2+1 | #VALOR! | =SUMAPRODUCTE(A1:A2+1) | 5

## CREIXEMENT

Calcula els punts de la tendència exponencial d'una matriu.

#### Sintaxi

CREIXEMENT(DadesY [; [DadesX ] [; [NovesDadesX ] [;; TipusDeFunció ] ] ]))

DadesY representa la matriu de dades Y.

DadesX (opcional) representa la matriu de dades X.

DadesNovesX (opcional) representa la matriu de dades X, en què es tornen a calcular els valors.

TipusDeFunció (opcional). Si TipusDeFunció = 0, es calcularan les funcions que tinguen la forma y = m^x. En cas contrari, es calcularan les funcions y = b*m^x.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els seguïsca. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Aquesta funció retorna una matriu i es tracta de la mateixa manera que la resta de funcions de matriu. Seleccioneu un interval on vulgueu que apareguen les respostes i seleccioneu la funció. Tot seguit, seleccioneu DadesY. Introduïu altres paràmetres (si cal), activeu Matriu i feu clic a D'acord.

## DETERMM

Retorna la matriu determinant d'una matriu. Esta funció retorna un valor en la cel·la actual; no cal definir una àrea per als resultats.

#### Sintaxi

DETERMM(Matriu)

Matriu representa una matriu quadrada en la qual es defineixen els determinants.

Trobareu una introducció general a l'ús de les funcions matricials a la part superior d'aquesta pàgina.

En trobareu més informació a l'inici de la pàgina.

## ESTLIN

Retorna una taula d'estadístiques per a la línia recta que encaixa millor amb el grup de dades.

#### Sintaxi

LINEST(data_Y [; data_X [; linearType [; stats]]])

Dades_Y és una sola fila o un interval de columnes que indica les coordenades y en un conjunt de punts de dades.

Dades_X és una fila única o un interval de columnes corresponent que especifica les coordenades x. Si s'omet Dades_X, es prendrà 1, 2, 3, ..., n per defecte. Si hi ha més d'un conjunt de variables, Dades_X pot ser un interval amb files o columnes múltiples corresponents.

ESTLIN busca la línia recta y = a + bx que encaixi millor amb les dades mitjançant la regressió lineal (el mètode dels mínims quadrats). Si hi ha més d'un conjunt de variables, la línia recta serà y = a + b1x1 + b2x2 ... + bnxn.

If linearType is FALSE the straight line found is forced to pass through the origin (the constant a is zero; y = bx). If omitted, linearType defaults to TRUE (the line is not forced through the origin).

If stats is omitted or FALSE only the top line of the statistics table is returned. If TRUE the entire table is returned.

ESTLIN retorna una taula (una matriu) d'estadístiques com la següent i s'ha d'introduir com una fórmula matricial (per exemple, prement OrdreCtrl+Maj+Retorn, en lloc de només Retorn).

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els seguïsca. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Esta funció retorna una matriu i es tracta de la mateixa manera que les altres funcions de matriu. Seleccioneu un interval per inserir-hi les respostes i tot seguit seleccioneu la funció. Seleccioneu Dades_Y. Si voleu, podeu introduir altres paràmetres. Seleccioneu Matriu i feu clic a D'acord.

Els resultats que retorna el sistema (si estadístiques = 0), mostraran almenys el pendent de la recta de regressió i la seua intersecció amb l'eix Y. Si estadístiques no és igual a 0, es mostraran altres resultats.

### Altres resultats d'ESTLIN:

Examineu els exemples següents:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | Valor residual |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #ND
5 | 7 | 12 | 108 |  | 13,21 | 4 | #ND
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #ND
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

La columna A conté diversos valors X1; la columna B, diversos valors X2, i la columna C, els valors Y. Ja heu introduït els valors en el full de càlcul. Heu configurat E2:G6 en el full de càlcul i heu activat l'Auxiliar de funcions. Perquè la funció ESTLIN funcione, heu d'haver activat la casella de selecció Matriu a l'Auxiliar de funcions. Tot seguit, seleccioneu els valors següents en el full de càlcul (o introduïu-los mitjançant el teclat):

Dades_Y és C2:C8

Dades_X és A2:B8

TipusLineal i estadístiques s'han definit a 1.

Tan bon punt feu clic a D'acord, el LibreOffice Calc emplenarà l'exemple anterior amb els valors de la funció ESTLIN, tal com es mostra a l'exemple.

La fórmula que apareix a la barra de fórmules correspon a cadascuna de les cel·les de la matriu ESTLIN {=ESTLIN(C2:C8;A2:B8;1;1)}.

Això representa els valors ESTLIN calculats:

E2 i F2: pendent m de la recta de regressió y=b+m*x per als valors x1 i x2. Els valors s'indiquen en l'orde invers; és a dir, el pendent d'x2 apareix a E2 i el pendent d'x1 es mostra a F2.

G2: intersecció de b amb l'eix y.

E3 i F3: error estàndard del valor del pendent.

G3: error estàndard de la intercepció.

E4: RQUAD

F4: error estàndard de la regressió calculat per al valor d'Y.

E5: valor F de l'anàlisi de variància.

F5: graus de llibertat de l'anàlisi de variància.

E6: suma dels quadrats de les desviacions dels valors Y estimats des de la mitjana lineal.

F6: suma del quadrat de la desviació del valor Y estimat des dels valors Y indicats.

En trobareu més informació a l'inici de la pàgina.

## ESTLOG

Esta funció calcula l'ajustament de les dades introduïdes en forma de corba de regressió exponencial (y=b*m^x).

#### Sintaxi

LOGEST(DataY [; DataX [; FunctionType [; Stats]]])

DadesY representa la matriu de dades Y.

DadesX (opcional) representa la matriu de dades X.

TipusDeFunció (opcional). Si Tipus_Funció = 0, es calcularan les funcions amb la forma y = m^x. Altrament, es calcularan les funcions y = b*m^x.

Estadístiques (opcional). Si Estadístiques=0, només es calcula el coeficient de regressió.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els seguïsca. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Vegeu ESTLIN. Tanmateix, no es retornarà cap suma quadrada.

## FREQUENCIA

Indicates the frequency distribution in a one-column-array. The function counts the number of values in the Data array that are within the values given by the Classes array.

#### Sintaxi

FREQUENCIA(Dades; Classes)

Dades representa la referència cap als valors que s'han de comptar.

Classes representa la matriu dels valors límit.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

Trobareu una introducció general a les funcions de matriu a la part superior d'esta pàgina.

#### Exemple

A la taula següent, la columna A mostra valors de mesura sense ordenar. La columna B conté el límit superior que heu introduït per a les classes en què voleu dividir les dades de la columna A. En funció del límit que hàgeu introduït a B1, la funció FREQUENCIA retorna el nombre de valors mesurats que són més petits o iguals que 5. Com que el límit de B2 és 10, la funció FREQUENCIA retorna el segon resultat com el nombre de valors mesurats que són majors de 5 i menors o iguals a 10. El text que heu introduït a B6, ">25", només s'utilitza com a referència.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Seleccioneu un interval, en una sola columna, on s'introduirà la freqüència en funció dels límits de classe. Heu de seleccionar un camp més que el camp superior de la classe. En este exemple, seleccioneu l'interval C1:C6. Activeu la funció FREQUENCIA des de l'Auxiliar de funcions. Seleccioneu l'interval Dades a (A1:A11) i, tot seguit, seleccioneu l'interval Classes en el qual hàgeu introduït els límits de classe (B1:B6). Activeu la casella de selecció Matriu i feu clic a D'acord. Apareixerà el comptatge de la freqüència en l'interval C1:C6.

En trobareu més informació a l'inici de la pàgina.

## MINVERSA

Retorna la matriu inversa.

#### Sintaxi

MINVERSA(Matriu)

Matriu representa una matriu quadrada que s'ha d'invertir.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Seleccioneu un interval quadrat i trieu MINVERSA. Seleccioneu la matriu obtinguda, seleccioneu el camp Matriu i feu clic a D'acord.

## MULTM

Calcula el producte de dues matrius. El nombre de columnes de la matriu 1 ha de coincidir amb el nombre de files de la matriu 2. La matriu quadrada té el mateix nombre de files i de columnes.

#### Sintaxi

MMULT(Array 1; Array 2)

Array 1 represents the first array used in the array product.

Array 2 represents the second array with the same number of rows.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Select a square range. Choose the MMULT function. Select Array 1, then select Array 2. Using the Function Wizard, mark the Array check box. Click OK. The output array will appear in the first selected range.

## MUNIT

Retorna la matriu quadrada unitària d'una mida determinada. La matriu unitària és una matriu quadrada on els elements diagonals principals són iguals a 1 i els altres elements de matriu són iguals a 0.

#### Sintaxi

MUNIT(Dimensions)

Dimensions fa referència a la mida de la unitat de matriu.

Trobareu una introducció general a les funcions de matriu a la part superior d'esta pàgina.

#### Exemple

Seleccioneu un interval quadrat en el full de càlcul; per exemple, d'A1 a E5.

Sense desseleccionar l'interval, seleccioneu la funció MUNIT. Activeu la casella de selecció Matriu. Introduïu les dimensions de la unitat de matriu, en este cas 5, i feu clic a D'acord.

You can also enter the =MUNIT(5) formula in the last cell of the selected range (E5), and press Shift + Command + EnterShift + Ctrl + Enter.

Es mostra una matriu unitària amb l'interval A1:E5.

En trobareu més informació a l'inici de la pàgina.

## SUMAPRODUCTE

Multiplica els elements corresponents de les matrius indicades i retorna la suma d'estos productes.

#### Sintaxi

SUMPRODUCT(Array 1[; Array 2;][...;[Array 255]])

Array 1[; Array 2;][...;[Array 255]] represent arrays whose corresponding elements are to be multiplied.

Almenys una matriu ha de formar part de la llista d'arguments. Si només es dona una matriu se sumen tots els elements de la matriu. Si es dona més d'una matriu, totes han de ser de la mateixa mida.

#### Exemple

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMAPRODUCTE(A1:B3;C1:D3) retorna 397.

Càlcul: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Podeu utilitzar SUMAPRODUCTE per calcular el producte escalar de dos vectors.

SUMAPRODUCTE retorna un sol nombre; no cal introduir la funció com una fórmula matricial.

En trobareu més informació a l'inici de la pàgina.

## SUMAX2MENYSY2

Retorna la suma de la diferència dels quadrats dels valors corresponents en dues matrius.

#### Sintaxi

SUMAX2MENYSY2(MatriuX; MatriuY)

MatriuX representa la primera matriu, els elements de la qual s'han d'elevar al quadrat i s'han de sumar.

MatriuY representa la segona matriu, els elements de la qual s'han d'elevar al quadrat i s'han de restar.

En trobareu més informació a l'inici de la pàgina.

## SUMAX2MESY2

Retorna la suma de la suma dels quadrats dels valors corresponents en dues matrius.

#### Sintaxi

SUMAX2MESY2(MatriuX; MatriuY)

MatriuX representa la primera matriu, els elements de la qual s'han d'elevar al quadrat i s'han de sumar.

MatriuY representa la segona matriu, els elements de la qual s'han d'elevar al quadrat i s'han de sumar.

En trobareu més informació a l'inici de la pàgina.

## SUMAXMENYSY2

Afig els quadrats de la variància entre els valors corresponents en dues matrius.

#### Sintaxi

SUMAXMENYSY2(MatriuX; MatriuY)

MatriuX representa la primera matriu, els elements de la qual s'han de restar i s'han d'elevar al quadrat.

MatriuY representa la segona matriu, els elements de la qual s'han de restar i s'han d'elevar al quadrat.

En trobareu més informació a l'inici de la pàgina.

## TENDENCIA

Retorna valors seguint una tendència lineal.

#### Sintaxi

TENDENCIA(DadesY [; DadesX [; NovesDadesX [; TipusLineal]]])

DadesY representa la matriu de dades Y.

DadesX (opcional) representa la matriu de dades X.

DadesNovesX (opcional) representa la matriu de les dades X, que s'utilitzen per tornar a calcular els valors.

TipusLineal (opcional). Si TipusLineal = 0, es calcularan les línies a través del punt zero. Altrament, també es calcularan les línies de desplaçament. El valor per defecte és TipusLineal <> 0.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els seguïsca. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

En trobareu més informació a l'inici de la pàgina.

#### Exemple

Seleccioneu l'interval de full de càlcul on han d'aparèixer les dades de tendència i, a continuació, seleccioneu la funció. Introduïu les dades de eixida o seleccioneu-les amb el ratolí. Finalment, activeu el camp Matriu i feu clic a D'acord. Es mostraran les dades de tendència que s'han calculat a partir de les dades d'eixida.

## TRANSPOSA

Transposa les files i les columnes d'una matriu.

#### Sintaxi

TRANSPOSA(Matriu)

Matriu representa la matriu del full de càlcul que s'ha de transposar.

Trobareu una introducció general a l'ús de les funcions de matriu a la part superior d'esta pàgina.

#### Exemple

In the spreadsheet, select the range in which the transposed array can appear. If the original array has n rows and m columns, your selected range must have at least m rows and n columns. Then enter the formula directly, select the original array and press Shift + Command + EnterShift + Ctrl + Enter. Or, if you are using the Function Wizard, mark the Array check box. The transposed array appears in the selected target range and is protected automatically against changes.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

The above table is 2 rows, 4 columns. In order to transpose it, you must select 4 rows, 2 columns. Assuming you want to transpose the above table to the range A7:B10 (4 rows, 2 columns) you must select the entire range and then enter the following:

TRANSPOSA(A1:D2)

Then make sure to enter it as matrix formula with Shift + Command + EnterShift + Ctrl + Enter. The result will be as follows:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

Temes relacionats

Funcions per categoria

Ens cal la vostra ajuda!