Vsebina

# Funkcija STYLE

Uveljavi slog v celici, ki vsebuje formulo. Po navedenem času lahko uveljavite drug slog.

Ta funkcija vedno vrne številsko vrednost 0, kar omogoča njeno rabo z dodajanjem funkcije STYLE drugim funkcijam v isti celici brez spreminjanja njene vrednosti.

Funkcije STYLE ne smete uporabljati brez tehtnega razloga, njen namen je uporaba z asinhronimi funkcijami dodatka za vizualno obveščanje o razpoložljivosti rezultata. V skoraj vseh drugih primerih je uporaba pogojnega oblikovanja boljša izbira.

### Skladnja

STYLE("slog" [; čas [; "slog2"]])

Slog je ime sloga celice, ki ga želimo uveljaviti za celico. Imena slogov moramo vnesti v narekovajih in ne razločujejo med velikimi in malimi črkami.

Čas (neobvezno) je čas v sekundah. Po preteku tega časa se uveljavi slog, določen v slog2. Če ta parameter izpustimo, se slog po preteku navedenega časa ne bo spremenil.

Slog2 (neobvezno) je ime za slog celice, ki ga želimo uporabiti v celici po preteku časa, določenega s parametrom Čas. Če ta parameter izpustimo, funkcija privzame vrednost »Privzeto«.

V funkcijah LibreOffice Calc lahko parametre, ki niso označeni kot »zahtevani«, izpustite le tedaj, ko ne sledi noben parameter. Če sta npr. za funkcijo s štirimi parametri prva dva označena kot »zahtevano«, lahko izpustite parameter 4 ali parametra 3 in 4, ne smete pa izpustiti zgolj parametra 3.

### Primeri

=10+STYLE("Dobro",60,"Nevtralno")

Vnese vrednost 10 v celico in uveljavi slog z imenom »Dobro«. Po 60 s uveljavi slog »Nevtralno«.

=A1*A2+STYLE(IF(CURRENT()<100,"Slabo","Dobro"))

Vnese rezultat množenja vrednosti v celicah A1 in A2 ter uveljavi slog »Slabo«,če je rezultat manjši kot 100, sicer uveljavi slog »Dobro«. Tukaj je uporabljena funkcija CURRENT() za pridobivanje trenutno ocenjene vrednosti funkcije v celici.

="Skupaj"&T(STYLE("Rezultat"))

Vnese besedilo »Skupaj« v celico in uveljavi slog »Rezultat«. Upoštevajte, da se ta primer ukvarja z besedilnimi vrednostmi, odtod je potrebno izhod funkcije STYLE dodati besedilu z operatorjem &. Funkcija T() se uporablja za preprečitev, da bi končnemu besedilu dodali število »0«.

#### Tehnični podatki

Ta funkcija NI del standarda Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Imenski prostor je

ORG.OPENOFFICE.STYLE

Podobne teme

Stran wiki o funkciji STYLE (v angl.).

Funkcije preglednic

Dodeljevanje oblik s formulo

Funkcija CURRENT

Funkcija T

Podprite nas!