Função PROCX

Sumário

# PROCX

Procura um valor numa matriz e retorna uma referência a uma célula ou intervalo de células.

A função PROCX é uma substituta moderna e flexível para as funções tais como PROCV, PROCH, e PROC. PROCX permite correspondências aproximadas e exatas, caracteres curingas (* ?) ou expressões regulares para correspondências parciais, e pesquisas em intervalos verticais e horizontais. PROCX pode fazer pesquisa reversa e oferece opção de pesquisa binária acelerada quando tratar grandes conjuntos de dados.

### Sintaxe

PROCX( [Critério de pesquisa] ; Matriz de pesquisa ; Matriz resultante [ ; [ Resultado quando não encontrado] [ ; [Modo de conferência] [ ;Modo de pesquisa] ] ] )

Critério de pesquisa: (opcional) o valor de qualquer tipo a pesquisar em Matriz de pesquisa. Se omitido, PROCX retorna as células em branco encontradas em Matriz de pesquisa.

Matriz de pesquisa: é a referência a matriz a pesquisar. A matriz deve ser de 1 dimensão e deve estar contida numa só planilha.

Matriz resultante: é a referência da matriz ou intervalo a retornar.

Se Matriz resultante for um intervalo de células, a função PROCX deve ser inserida como fórmula de matriz.

Resultado quando não encontrado: um texto ou conteúdo de célula a retornar se o valor de Critério de pesquisa não for encontrado. Se uma correspondência válida não for encontrada e Resultado quando não encontrado for omitido, a função retorna o erro #N/DISP.

Modo de correspondência: (opcional) especifica o modo de correspondência. O valores podem ser:

- 0: correspondência exata (padrão). Se o valor de Critério de pesquisa não for encontrado e o texto de Resultado quando não encontrado é omitido, retorna o erro #N/DISP.

- -1: tentativa de correspondência exata. Se o valor de Critério de pesquisa não for encontrado, retorna o item mais próximo a menor.

- 1: tentativa de correspondência exata. Se o valor de Critério de pesquisa não for encontrado, retorna o item mais próximo a maior.

- 2: correspondência por caracteres coringa onde os caracteres * (múltiplos caracteres), ? (caractere únicos), e ~ tem significados especiais.

- 3: correspondência por expressão regular.

Modo de Pesquisa: (opcional) especifica o modo de pesquisa a utilizar.

- 1: retorna a primeira correspondência começando pelo primeiro item de Matriz de pesquisa (padrão).

- -1: pesquisa reversa. Retorna a primeira ocorrência começando pelo último item de Matriz de pesquisa.

- 2 - Pesquisa binária que depende da Matriz de pesquisa ser ordenada em ordem crescente. Se não for ordenada, serão retornados resultados inválidos.

- -2 - Pesquisa binária que depende da Matriz de pesquisa ser ordenada em ordem decrescente. Se não for ordenada, serão retornados resultados inválidos.

Os valores 2 e 3 de Modo de correspondência não podem ser combinados com a pesquisa binária (valores 2 ou -2 de Modo de pesquisa).

Qualquer um dos argumentos opcionais pode ser omitido. Um argumento opcional requer que todos os separadores anteriores estejam presentes.

### Exemplos

Tem-se uma pequena tabela de banco de dados ocupando o intervalo de células A1: DO4 e contendo informações básicas sobre 118 elementos químicos. A primeira coluna contém os cabeçalhos das linhas “Elemento”, “Símbolo”, “Número Atômico” e “Massa Atômica Relativa”. As colunas subsequentes contêm as informações relevantes para cada um dos elementos, ordenadas da esquerda para a direita pelo número atômico. Por exemplo, as células B1: B4 contêm “Hidrogênio”, “H”, “1” e “1.008”, enquanto as células DO1: DO4 contêm “Oganesson”, “Og”, “118” e “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Elemento | Hidrogênio | Hélio | Lítio | ... | Oganesson
2 | Símbolo | H | He | Li | ... | Og
3 | Número atômico | 1 | 2 | 3 | ... | 118
4 | Massa atômica relativa | 1.008 | 4.0026 | 6.94 | ... | 294

{=PROCX("Número atômico";A2:A4;A2:DO4)} retorna a matriz

Número atômico | 1 | 2 | 3 | ... | 118

{=PROCX("Hélio";B1:DO1;B1:DO4)} retorna a matriz

Hélio
He
2
4.0026

{=PROCX("Kryptonite";B1:DO1;B1:DO4;"Elemento desconhecido")} retorna a matriz {"Elemento desconhecido","Elemento desconhecido","Elemento desconhecido","Elemento desconhecido"}.

#### Informação técnica

Esta função está disponível desde o LibreOffice 24.8.

Esta função não faz parte do padrão Open Document Format for Office Applications (OpenDocument) Versão 1.3. Parte 4: Formato de Fórmula Recalculada (OpenFormula). O espaço de nomes é

COM.MICROSOFT.XLOOKUP

Tópicos relacionados

CORRESPX

Página wiki da função CORRESPX.

♥ Doe para nosso projeto! ♥